# This awk script finds names, titles, and keywords in S-PLUS help files,
# and returns a summary of information on stdout.

# The usage is awk -f <this file> filename1 [...]

# (the help files should have .FN(s), .TL, and .KW(s).
BEGIN {
	grokking_fn = 1;
	grokking_tl = 2;
	grokking_kw = 3;
	OFILENAME = FILENAME;
}
{

# If the file changes, show what information we've gleaned from lasts file,
# and reset for the this file.

	if (FILENAME != OFILENAME) {
		# show summary is repeated in the END section to get
		# the summary for the last file.
		# show summary for this file.
		for (name=0; name<c_fn; name++) {
			printf("%s", fn[name]);
			printf("~~~");
			for (i=0; i<c_tl; i++) {
				printf("%s", tl[i]);
				if (i != c_tl-1) printf(" ");
			}
			printf("~~~");
			for (i=0; i<c_kw; i++) {
				printf("%s", kw[i]);
				if (i != c_kw-1) printf(" ");
			}
			printf("\n");
		}

		c_fn = 0; c_kw = 0; c_tl = 0;
		grokking = 0;
	}

# Figure out what special information we're grokking, if any.

	if (substr($1, 1, 1) == ".") {
		start = 2;
		if ($1 == ".FN") {
			grokking = grokking_fn;
		} else if ($1 == ".TL") {
			grokking = grokking_tl;
		} else if ($1 == ".KW") {
			grokking = grokking_kw;
		} else {
			grokking = 0;
		}
	} else {
		start = 1;
	}

# If grokking special information, add the information to the right list.

	if (grokking != 0) {
		for (i=start; i<=NF; i++) {
			if (grokking == grokking_fn) {
				fn[c_fn++] = $i;
			} else if (grokking == grokking_tl) {
				tl[c_tl++] = $i;
			} else if (grokking == grokking_kw) {
				kw[c_kw++] = $i;
			} else {
				printf("Unknown grokking code: %d\n", grokking);
			}
		}
	}
	OFILENAME = FILENAME;
}
END {
	# show summary for this file.
	for (name=0; name<c_fn; name++) {
		printf("%s", fn[name]);
		printf("~~~");
		for (i=0; i<c_tl; i++) {
			printf("%s", tl[i]);
			if (i != c_tl-1) printf(" ");
		}
		printf("~~~");
		for (i=0; i<c_kw; i++) {
			printf("%s", kw[i]);
			if (i != c_kw-1) printf(" ");
		}
		printf("\n");
	}
}