%% $RCSfile: fcncallgen.ttlc,v $
%% File : fcncallgen.tlc generated from fcncallgen.ttlc revsion 1.4
%% $Date: 2000/04/26 17:25:26 $
%%
%% Author:     Pete Szpak 29 Jul 1998
%% Updated by: Mojdeh Shakeri 11 Nov 1999
%%
%% Copyright 1990-2000 The MathWorks, Inc.
%%
%% Abstract:
%%   Function-call generator block target file.

%implements fcncallgen "C"

%function Outputs(system, block) Output
  %openfile tmpBuffer
  %foreach fcnCallIdx = NumSFcnSysOutputCalls
    %% call the downstream system
    %with SFcnSystemOutputCall[fcnCallIdx]
      %% skip unconnected function call outputs
      %if LibIsEqual(BlockToCall, "unconnected")
	%continue
      %endif
      %assign sysIdx = BlockToCall[0]
      %assign blkIdx = BlockToCall[1]
      %assign ssBlock = System[sysIdx].Block[blkIdx]
      %assign sysToCall = System[ssBlock.ParamSettings.SystemIdx]
      %assign num       = SIZE(SFcnParamSettings.Counter, 1)
      %assign idx       = (num > 1) ? fcnCallIdx : 0
      %assign count     = CAST("Number",SFcnParamSettings.Counter[idx])
      %openfile tmp2Buffer
      %<LibCallFCSS(sysToCall, tSimStruct, FcnPortElement, ...
	ParamSettings.SampleTimesToSet[0][1])>\
      %closefile tmp2Buffer
      %if (!WHITE_SPACE(tmp2Buffer))
	%if count > 1
	  {
	    int_T i = 0;
	    for(i = 0; i < %<count> ; ++i){
	%endif
	%<tmp2Buffer>\
	%if count > 1
	    }
	  }
	%endif
      %endif
    %endwith
  %endforeach
  %closefile tmpBuffer
  %% output buffer
  %if !WHITE_SPACE(tmpBuffer)
    %assign type = ParamSettings.FunctionName
    /* %<Type> (%<type>) Block: %<Name> */
    %<tmpBuffer>

  %endif
%endfunction

%% [EOF] fcncallgen.tlc