%% $RCSfile: sdsphist2.tlc,v $
%% $Revision: 1.4 $ 
%% $Date: 2000/06/15 20:37:41 $
%%
%% Copyright 1995-2000 The MathWorks, Inc.
%%
%% Abstract: Histogram Block

%implements sdsphist2 "C"

%% Function: InitializeConditions =============================================
%%
%function InitializeConditions(block, system) Output
	/* DSP Blockset Histogram (%<ParamSettings.FunctionName>) - %<Name> */
	%%
	%%
	%assign isMinComplex = CAST("Boolean",(Min.ComplexSignal == "yes"))
	%assign isMaxComplex = CAST("Boolean",(Max.ComplexSignal == "yes"))
	%%
	%if isMinComplex
		%assign min_mag = CMAGSQ(%<LibBlockParameterValue(Min,"%<tRealPart>0")>,%<LibBlockParameterValue(Min,"%<tImagPart>0")>)
	%else
		%assign min_mag = LibBlockParameterValue(Min,0)
    %endif
    %%
    %<LibBlockDWork(MinMag,"", "", 0)> = %<min_mag>;
    %%
    %if isMaxComplex
		%assign max_mag = CMAGSQ(%<LibBlockParameterValue(Max,"%<tRealPart>0")>,%<LibBlockParameterValue(Max,"%<tImagPart>0")>)
	%else
		%assign max_mag = LibBlockParameterValue(Max,0)
	%endif
	%%
	%<LibBlockDWork(MaxMag,"", "", 0)> = %<max_mag>;
	%%
	%assign running   = CAST("Boolean",(SFcnParamSettings.isRunning == "Yes"))
	%assign normalize = CAST("Boolean",(SFcnParamSettings.isNorm == "Yes"))
	%assign Nbins     = CAST("Real",SFcnParamSettings.Nbins)
	%%
	%<LibBlockDWork(Idelta,"", "", 0)> = %<Nbins> / %<max_mag - min_mag>;
	%%
	%if running
		%if normalize
			%<LibBlockDWork(Iteration,"", "", 0)> = 0.0;
		%endif

		/* Set all histogram bin counts to zero: */
		memset(%<LibBlockDWorkAddr(BinCount,"", "", 0)>, 0, (uint32_T)(%<Nbins>)*sizeof(uint32_T));
	%endif
%endfunction %% InitializeConditions


%% Function: Outputs ==========================================================
%%
%function Outputs(block, system) Output
  /* DSP Blockset Histogram (%<ParamSettings.FunctionName>) - %<Name> */
  %%
  %assign INPORT_DATA  = 0
  %assign INPORT_RESET = 1
  %assign OUTPORT      = 0
  %%
  %assign running   = CAST("Boolean",(SFcnParamSettings.isRunning == "Yes"))
  %assign normalize = CAST("Boolean",(SFcnParamSettings.isNorm == "Yes"))
  %assign Nbins     = SFcnParamSettings.Nbins
  %assign umin      = LibBlockDWork(MinMag,"", "", 0)
  %assign umax      = LibBlockDWork(MaxMag,"", "", 0)
  %assign idelta    = LibBlockDWork(Idelta,"", "", 0)
  %%
  %assign isFullMatrix = LibBlockInputSignalIsFullMatrix(INPORT_DATA)
  %assign cplx         = (LibBlockInputSignalIsComplex(INPORT_DATA) != 0)
  %assign dType        = (cplx) ? "creal_T" : "real_T"
  %assign width        = LibBlockInputSignalWidth(INPORT_DATA)
  %assign dims         = LibBlockInputSignalDimensions(INPORT_DATA)  
  %assign frame        = LibBlockInputSignalIsFrameData(INPORT_DATA)
  %assign nChans       = (frame || isFullMatrix) ? dims[1] : 1
  %assign nSamps       = (frame || isFullMatrix) ? dims[0] : width
  %%
  %%
  %% Running and Non-Running:
  %%
  {
	%%
	%if !running
		real_T   *y   = %<LibBlockOutputSignalAddr(OUTPORT, "","", 0)>;
	%else
      %%
      %% Block could be multirate if and only if it has more than
      %% one input port (eg, a reset input).  If it is multirate,
      %% generate "sample hit" conditional so code executes at the
      %% block's base rate, and not the overall model base rate.
      %%
      %assign differentPortRates = !LibIsSFcnSingleRate(block)
      %%
      %if differentPortRates
      if (%<LibIsSFcnSampleHit("InputPortIdx0")>) { %<LibTaskSFcnComment("InputPortIdx0")>
      %endif
        uint32_T *h   = %<LibBlockDWorkAddr(BinCount, "", "", 0)>;
	%endif
	%<dType> *u   = %<LibBlockInputSignalAddr(INPORT_DATA, "","", 0)>;
    real_T    val = 0.0;
	int_T     i;

	%if !running
		/* Initialize all bins to zero: */
		int_T n;
		for(n=0; n < %<Nbins*nChans>; n++) {
			y[n] = 0.0;
		}

	%endif

	%% Only have a reset port in Running mode.
	%assign isRstPort = CAST("Boolean",(SFcnParamSettings.isRstPort == "Yes"))

    %if isRstPort
       if (%<LibBlockInputSignal(INPORT_RESET,"","",0)> != 0.0) {	  
         memset((void *)h, 0, %<Nbins*nChans>*sizeof(uint32_T));	 
         %%
		 %if normalize
			%<LibBlockDWork(Iteration, "", "", 0)> = 0.0;
		 %endif
       }
    %endif
	{    
	%if nChans > 1
		int_T k = %<nChans>;
		while(k-- > 0) {
	%endif
		%if nSamps > 1
			int_T j = %<nSamps>;

			while(j-- > 0) {
		%endif
				%if cplx
					val = sqrt(CMAGSQ(*u));
					u++;
				%else
					val = *u++;
				%endif

				  /* Update appropriate histogram bin: */
				  if (val <= %<umin>) {
						i = 0;
				  } else if (val > %<umax>) {
						i = %<Nbins-1>;
				  } else {
						i = (int_T)(ceil((val-%<umin>) * %<idelta>) - 1);
				  }
				  %if !running
					(*(y + i))++;
				  %else
					(*(h + i))++;
				  %endif
		%if nSamps > 1
			}
		%endif
	%if nChans > 1
		%if !running
			y += %<Nbins>;					
		%else
			h += %<Nbins>;					
		%endif		
		}
    %endif
	}

		%if (!running & normalize)
			%if nChans > 1
				y -= %<Nbins*nChans>; 
			%endif
			i  = %<Nbins*nChans>;
			while (i-- > 0) {
				*y++ *= %<1.0 / nSamps>;   %% scale = 1/framesize or 1/width
			}
		%endif
		%if running
			%if normalize
			{
				/* Copy normalized bin count to output: */
				real_T *iter_cnt = %<LibBlockDWorkAddr(Iteration, "", "", 0)>;
				real_T scale;
				int_T  i;

				(*iter_cnt)++;
				scale = 1 / (*iter_cnt * %<nSamps>);
				%if nChans > 1
					h -= %<Nbins*nChans>;
				%endif

				for(i=0; i < %<Nbins*nChans>; i++) {
					%<LibBlockOutputSignal(OUTPORT, "i", "", 0)> = scale * (real_T)(*h++);
				}
			}
			%else
			{
				/* Copy unnormalized bin count to output: */
				int_T i;
				%if nChans > 1
					h -= %<Nbins*nChans>;
				%endif

				for (i=0; i < %<Nbins*nChans>; i++) {
					%<LibBlockOutputSignal(OUTPORT, "i", "", 0)>  = (real_T)(*h++);
				}
			} 
		%endif
	%endif       
  %if running
    %if differentPortRates
      }
    %endif
  %endif
  }
%endfunction

%% [EOF] sdsphist2.tlc