%% $RCSfile: sdspdiff2.tlc,v $
%% $Revision: 1.9 $ $Date: 2000/08/15 22:34:53 $
%%
%% Copyright 1995-2000 The MathWorks, Inc.
%%
%% Abstract: Element-to-element difference along a vector

%implements sdspdiff2 "C"


%% Function: BlockInstanceSetup ===============================================
%%
%function BlockInstanceSetup(block, system) void
  %assign INPORT  = 0
  %assign OUTPORT = 0
  %%
  %assign inDims  = LibBlockInputSignalDimensions(INPORT)
  %assign inRows  = inDims[0]
  %%
  %assign numDims = LibBlockOutputSignalNumDimensions(OUTPORT)
  %assign outDims = LibBlockOutputSignalDimensions(OUTPORT)
  %assign outCols = (numDims == 2) ? outDims[1] : 1
  %assign outRows = outDims[0]
  %%
  %assign cmplx   = LibBlockOutputSignalIsComplex(OUTPORT)
  %assign DType   = cmplx ? "creal_T" : "real_T"
  %%
  %assign direction           = SFcnParamSettings.Direction
  %assign ColumnDiff          = (direction == 2) && (numDims==2)
  %assign framebased          = LibBlockInputSignalIsFrameData(INPORT)
  %assign frameColRunningMode = (framebased && ColumnDiff)
  %%
  %assign block = block   + INPORT  + OUTPORT + numDims + ...
                  outCols + outRows + inRows  + cmplx   + ...
                  DType   + frameColRunningMode + ColumnDiff
%endfunction %% BlockInstanceSetup


%% Function: Start =============================================================
%% Abstract:
%%
%function Start(block, system) Output
  %if !LibIsEqual(TID, "constant")
    %if frameColRunningMode
      {
        /* For the first step the previous input equals ZERO */
        %<DType> *prev = %<LibBlockDWorkAddr(PreviousValue,"","",0)>;
        %if (%<outCols> > 1)
          const int_T outCols = %<outCols>;
          int_T c;
          for(c=0; c++<outCols; ) {
            %if !cmplx
              *prev++ = 0;
            %else
              prev->re   = 0;
              prev++->im = 0;
            %endif
          }
        %else
          %if !cmplx
            *prev = 0;
          %else
            prev->re = 0;
            prev->im = 0;
          %endif
        %endif
      }
    %endif
  %endif
%endfunction  %% Start


%% Function: Outputs ==========================================================
%%
%function Outputs(block, system) Output
  /* DSP Blockset Difference (%<ParamSettings.FunctionName>) - %<Name> */
  {
    %if numDims == 1
      /* Difference along vector */
      %<DiffVector(outRows)> \
    %elseif frameColRunningMode
      /* Framebased running difference */
      %<DiffFrame()> \
    %elseif ColumnDiff
      /* Difference along columns */
      %<DiffCol()> \
    %else
      /* Difference along rows */
      %<DiffRow()> \
    %endif
  }

%endfunction %% Outputs


%% Function: DiffFrame =========================================
%%
%function DiffFrame() Output 
    %<DType>   *prev    = %<LibBlockDWorkAddr(PreviousValue,"","",0)>;
    %<DType>   *y       = %<LibBlockOutputSignalAddr(OUTPORT,"","",0)>;
    %<DType>   *u       = %<LibBlockInputSignalAddr(INPORT,"","",0)>;
    %<DType>   *v       = u+1;  /* next */
    const int_T outRows = %<outRows>;
    const int_T outCols = %<outCols>;
    int_T       c;
    for(c=0; c++<outCols; ) {
      int_T r;
      %%
      %if !cmplx
        *y++ = *u - *prev;
      %else
        y->re   = u->re - prev->re;
        y++->im = u->im - prev->im;
      %endif
      %%
      for(r=1; r++<outRows; ) {
        %if !cmplx
          *y++ = *v++ - *u++;
        %else
          y->re   = v->re   - u->re;
          y++->im = v++->im - u++->im;
        %endif
      }
      *prev++ = *u++; /* Save last sample in frame */
      v++;            /* Skip first sample of next frame */
    }
%endfunction


%% Function: DiffCol ==========================================================
%%
%function DiffCol() Output 
    %if outCols > 1
        %<DType> *y       = %<LibBlockOutputSignalAddr(OUTPORT,"","",0)>;
        %<DType> *u       = %<LibBlockInputSignalAddr(INPORT,"","",0)>;
        %<DType> *v       = u+1;
        int_T     outRows = %<outRows>;
        int_T     outCols = %<outCols>;
        int_T     c;
        for(c=0; c++<outCols; ) {
            int_T r;
            for(r=0; r++<outRows; ) {
              %if cmplx
                 y->re     = v->re - u->re;
                 (y++)->im = (v++)->im - (u++)->im;
              %else
                  *y++ = *v++ - *u++;
              %endif
            }
            u++; v++; /* top of next input column */
        }
    %else
        %<DiffVector(outRows)> \
    %endif
%endfunction  %% DiffCol


%% Function: DiffRow ==========================================================
%%
%function DiffRow() Output 
    %if outRows > 1
        %<DType> *y       = %<LibBlockOutputSignalAddr(OUTPORT,"","",0)>;
        %<DType> *u       = %<LibBlockInputSignalAddr(INPORT,"","",0)>;
        int_T     inRows  = %<inRows>;
        int_T     outCols = %<outCols>;
        int_T     outRows = %<outRows>;
        int_T     r;
        for(r=0; r<outRows; r++) {
            int_T c;
            for(c=0; c<outCols; c++) {
                %if cmplx
                    int_T idx_out = c * outRows;
                    int_T idx1_in = c * inRows;
                    int_T idx2_in = idx1_in + inRows;

                    y[idx_out].re = u[idx2_in].re - u[idx1_in].re;
                    y[idx_out].im = u[idx2_in].im - u[idx1_in].im;
                %else
                    int_T idx    = c * inRows;
                    y[c*outRows] = u[idx+inRows] - u[idx];
                %endif
            }
            u++; /* start of next input row */
            y++; /* start of next output row */
        }
    %else
        %<DiffVector(outCols)> \
    %endif
%endfunction  %% DiffRow


%% Function: DiffVector ==========================================================
%%
%function DiffVector(outWidth) Output 
    %<DType> *y = %<LibBlockOutputSignalAddr(OUTPORT,"","",0)>;
    %<DType> *u = %<LibBlockInputSignalAddr(INPORT,"","",0)>;
    %<DType> *v = u+1;
    int_T outWidth = %<outWidth>;

    while(outWidth-- > 0) {
      %if cmplx
         y->re     = v->re - u->re;
         (y++)->im = (v++)->im - (u++)->im;
      %else
          *y++ = *v++ - *u++;
      %endif
    }
%endfunction  %% DiffVector


%% [EOF] $RCSfile: sdspdiff2.tlc,v $